XPath 3.0, XPath 2.0, XPath 1.0 / XPath-Funktionen / Zahlenfunktionen / max()

max()

max()

➪ Die max-Funktion berechnet den Maximalwert der Zahlen in der Sequenz (vorausgesetzt, es sind nur Werte enthalten, die auch als Zahlenwerte gecastet werden können). Die Funktion steht erst ab XSLT 2.0/XPath 2.0 zur Verfügung.

Auf dieser Seite:

Nehmen Sie eine Sequenz von Items, die sich aus einem XML-Dokument auswerten und durch das XPath-Statement "//Gehalt" ansprechen lässt. Dann ergibt ...


<xsl:template match="/">
    <ergebnis>
        <xsl:value-of select="max(//Gehalt)"/>
    </ergebnis>
</xsl:template>

... dieses Resultat:


<ergebnis>6789</ergebnis>

Selbst definierte Sequenzen ab XSL 2.0

Ebenso können Sie der max-Funktion auch eine selbst definierte Sequenz mitgeben.


<xsl:variable name="vseq" 
  select="7*25.99, 199, 1, (11 to 50)[. mod 9=1]"/>

Aus dem hier berechneten Wertebereich (181.93, 199, 1, 19, 28, 37, 46) wird mit der max-Funktion der Wert 199 ermittelt. Mit der -Funktion können Sie auch die Position dieses Wertes in der Sequenz ermitteln.


<xsl:template match="/">
    <max 
        index="{index-of($vseq, max($vseq))}">
        <xsl:value-of select="max($vseq)"/>
    </max>
</xsl:template>

Resultat:


<max index="2">199</max>

Wichtig ist auch hier, dass alle Items der Sequenz als Zahlen gecastet werden können. Das ist bei der folgenden Sequenz (1,2,3,4,5,'Hallo') nicht der Fall:


<ergebnis>
    <xsl:value-of select="max((1 to 5, 'Hallo'))"/>
</ergebnis>

In diesem Fall ist mit einer Fehlermeldung zu rechnen, z.B.


FORG0006: Cannot compare xs:integer with xs:string

Maximalwerte in XSL 1.0 ermitteln

Die max-Funktion steht erst ab XPath 2.0 zur Verfügung. Wer in XSLT 1.0 (je nach XSL-Prozessor) aus einer Nodeliste einen Maximalwert ermitteln möchte, kann die XPath-Achsen und verwenden. Die Ermittlung von max(//Gehalt) verläuft dann so:


<xsl:value-of 
     select="//Gehalt[not(
                      following::Gehalt &gt; . 
                      or 
                      preceding::Gehalt &gt; .)]"/>

Alternativ können Sie die Werte in eine Variable schreiben, diese mit absteigend sortieren und dann den ersten Wert auswählen.


<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:ms="urn:schemas-microsoft-com:xslt"
    xmlns:common="http://exslt.org/common"
    xmlns:math="http://exslt.org/math"
    xmlns:xalan="http://xml.apache.org/xalan">
  <xsl:template match="/">
    <xsl:variable name="vG">
      <erg>
        <xsl:for-each select="//Mensch">
          <xsl:sort select="Gehalt" 
                    data-type="number" 
                    order="descending"/>
          <wert><xsl:value-of select="Gehalt"/></wert>
        </xsl:for-each>
      </erg>
    </xsl:variable>
    <eee>
      <xsl:value-of select="$vG/erg/wert[1]"/>
    </eee>
  </xsl:template>
</xsl:stylesheet>

Das funktioniert jedoch nicht bei allen XSL-Prozessoren: Bei Verwendung von Xalan erhalten Sie eine ClassCastException.


Programmname: Xalan
java.lang.ClassCastException: 
org.apache.xpath.objects.XRTreeFrag 
cannot be cast to org.apache.xpath.objects.XNodeSet

Eine mögliche Lösung liegt in der Einbindung von xmlns:xalan="http://xml.apache.org/xalan" und dem Aufruf der nodeset-Methode.


<xsl:value-of select="xalan:nodeset($vG)//wert[1]"/>

Alternativ funktioniert bei Xalan auch die Einbindung von xmlns:common="http://exslt.org/common" und der Aufruf der common:node-set-Methode. Ebenso unterstützt Xalan auch die spezifischen Funktionen im Namespace xmlns:math="http://exslt.org/math". Damit wird ein Direktaufruf der max-Funktion möglich.


<xsl:value-of select="math:max(//Mensch/Gehalt)"/>

Die .NET-Klasse System.Xml.Xsl.XslCompiledTransform benötigt für dieses Konstrukt ebenfalls die node-set-Methode; verwendet wird hier der Namespace urn:schemas-microsoft-com:xslt. Alternativ funktioniert System.Xml.Xsl.XslCompiledTransform auch mit common:node-set.


<xsl:value-of 
     select="ms:node-set($vG)/erg/wert[last()]"/>
<!-- alternativ: -->
<xsl:value-of 
     select="common:node-set($vG)/erg/wert[last()]"/>

Maximalwerte mit C#.NET Scripting ermitteln

Wenn Sie in C#.NET mit der .NET-Klasse System.Xml.Xsl.XslCompiledTransform arbeiten, können Sie alternativ die Verarbeitung auch in das XSL-Stylesheet verlagern. Die NodeList //Gehalt wird dabei in ein Objekt der Klasse Xml.XPath.XPathNodeIterator abgebildet, das mit MoveNext() und Current.InnerXml in einer while-Schleife ausgewertet werden kann. Bei der Typkonvertierung auf Double ist dabei noch der Parameter System.Globalization.CultureInfo.InvariantCulture erforderlich, um den "." als Dezimaltrenner korrekt einzulesen.


<xsl:stylesheet 
     version="1.0" 
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
     xmlns:msxsl="urn:schemas-microsoft-com:xslt" 
     xmlns:csharp="http://csharp.org">
     <xsl:output method="xml" indent="yes"/>
     <msxsl:script 
            language="CSharp" 
            implements-prefix="csharp">
     <![CDATA[
public static double getmax(object o)
{
    System.Xml.XPath.XPathNodeIterator i;
    i = (System.Xml.XPath.XPathNodeIterator) o;
    double y = 0;
    double wert = 0;
    while(i.MoveNext())
    {        
        //y = Convert.ToDouble(i.Current.InnerXml.ToString(), 
        //    System.Globalization.CultureInfo.InvariantCulture);
        // besser: 
        y = i.Current.ValueAsDouble;
        if (y > wert) wert = y;
    }
    return wert;     
}
]]>
    </msxsl:script>
    <xsl:template match="/">
        <root>
            <xsl:value-of 
                 select="csharp:getmax(//Gehalt)"/>            
        </root>
    </xsl:template>
</xsl:stylesheet>

Der Transformationsaufruf erfordert noch ein gesondertes EnableScript:


using System.Xml.Xsl;
XslCompiledTransform t = new XslCompiledTransform();
XsltSettings settings  = new XsltSettings();
settings.EnableScript  = true;
t.Load(@"C:\wg\test.xsl", settings, null);
t.Transform(@"C:\wg\Ort_Elemente.xml", 
            @"C:\wg\output\ergebnis.xml");

Auch der Einsatz von LINQ stellt hier eine Alternative dar. (Vielen Dank für den Hinweis!)


<xsl:stylesheet 
    version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" 
    xmlns:csharp="http://csharp.org">
    <xsl:output method="xml" indent="yes"/>
    <msxsl:script implements-prefix="csharp" language="C#">
        <msxsl:assembly name="System.Core"/>
        <msxsl:using namespace="System.Linq"/>
        <![CDATA[
public double Max(XPathNodeIterator nodes)
{
  return nodes.OfType<XPathNavigator>().Max(nav => nav.ValueAsDouble);
}  
  ]]>
    </msxsl:script>
    <xsl:template match="/">
        <root>
            <xsl:value-of 
                select="csharp:Max(//Gehalt)"/>            
        </root>
    </xsl:template>
</xsl:stylesheet>

wg / 8. Mai 2018



Fragen? Anmerkungen? Tips?

Bitte nehmen Sie Kontakt zu mir auf.




sum()



Vielen Dank für Ihr Interesse an meiner Arbeit.


V.i.S.d.P.: Wilfried Grupe * Klus 6 * 37643 Negenborn

☎ 0151. 750 360 61 * eMail: info10@wilfried-grupe.de

www.wilfried-grupe.de/max.html